登录/注册
GcsSloop
1555
占位
1
占位
0
浏览量
占位
粉丝
占位
关注
实验3 转移指令跳转原理及其简单应用编程
GcsSloop
2022-01-13 17:04:17 2022-01-13
16
0
  1. 实验任务1
    assume cs:code, ds:data
    data segment
    x db 1, 9, 3
    len1 equ $ - x ; 符号常量, $指下一个数据项的偏移地址,这个示例中,是3
    y dw 1, 9, 3
    len2 equ $ - y ; 符号常量, $指下一个数据项的偏移地址,这个示例中,是9
    data ends
    code segment
    start:
    mov ax, data
    mov ds, ax
    mov si, offset x ; 取符号x对应的偏移地址0 -> si
    mov cx, len1 ; 从符号x开始的连续字节数据项个数 -> cx
    mov ah, 2
    s1:mov dl, [si]
    or dl, 30h
    int 21h
    mov dl, ' '
    int 21h ; 输出空格
    inc si
    loop s1
    mov ah, 2
    mov dl, 0ah
    int 21h ; 换行
    mov si, offset y ; 取符号y对应的偏移地址3 -> si
    mov cx, len2/2 ; 从符号y开始的连续字数据项个数 -> cx
    mov ah, 2
    s2:mov dx, [si]
    or dl, 30h
    int 21h
    mov dl, ' '
    int 21h ; 输出空格
    add si, 2
    loop s2
    mov ah, 4ch
    int 21h
    code ends
    end start
    

① line27, 汇编指令 loop s1 跳转时,是根据位移量跳转的。通过debug反汇编,查看其机器码, 分析其跳转的位移量是多少?(位移量数值以十进制数值回答)从CPU的角度,说明是如何计算得 到跳转后标号s1其后指令的偏移地址的。

 F2H=[11110010]补=[10001110]原=-14D

-14O=(D-19-2)H

② line44,汇编指令 loop s2 跳转时,是根据位移量跳转的。通过debug反汇编,查看其机器码, 分析其跳转的位移量是多少?(位移量数值以十进制数值回答)从CPU的角度,说明是如何计算得 到跳转后标号s2其后指令的偏移地址的。

 F0H=[11110000]补=[10010000]原=-16D

-16O=[29-37-2]H

  1. 实验任务2
    assume cs:code, ds:data
    data segment
    dw 200h, 0h, 230h, 0h
    data ends
    stack segment
    db 16 dup(0)
    stack ends
    code segment
    start:
    mov ax, data
    mov ds, ax
    mov word ptr ds:[0], offset s1  ;字
    mov word ptr ds:[2], offset s2  ;字
    mov ds:[4], cs
    mov ax, stack
    mov ss, ax
    mov sp, 16
    call word ptr ds:[0]             ;字  跳转
    s1: pop ax
    call dword ptr ds:[2]            ;双字  跳转
    s2: pop bx
    pop cx
    mov ah, 4ch
    int 21h
    code ends
    end start
    

① 根据call指令的跳转原理,先从理论上分析,程序执行到退出(line31)之前,寄存器(ax) = ? 寄存器 (bx) = ? 寄存器(cx) = ?

ax=0021

执行call word ptr ds:[0]时,先把当前的IP存起来,当前IP指向下一条命令,地址为0021,于是0021入栈

接着执行POP AX,将栈顶的内容弹出,保存至AX,于是AX的值就是0021

bx=0026

执行call dword ptr ds:[2]时,因为dword(双字),IP指向下一条指令的地址为076C:0026.于是0026先入栈,然后076C再入栈

接着执行POP BX,将栈顶的内容弹出,保存至BX,栈顶为0026,于是BX的值就是0026

cx=076C

接着执行POP CX,将栈顶的内容弹出,保存至CX,栈顶为076C,于是CX的值就是076C

  1. 实验任务3

编写8086汇编源程序task3.asm,在屏幕上以十进制形式输出data段中这一组连续的数据,数据和数据 之间以空格间隔。 要求: 编写子程序printNumber 功能:以十进制形式输出一个两位数 入口参数:寄存器ax(待输出的数据 --> ax) 出口参数:无 编写子程序printSpace 功能:打印一个空格 入口参数:无 出口参数:无 在主体代码中,综合应用寻址方式和循环,调用printNumber和printSpace, 实现题目要求。

assume cs:code, ds:data

data segment
        x db 99, 72, 85, 63, 89, 97, 55
        len equ $ - x
data ends

code segment
main:   mov ax, data
        mov ds, ax

        mov si, offset x
        mov cx, len
s1:     mov ah, 0
        mov al, [si]
        call printNumber   ;输出十进制数字
        call printSpace    ;输出空格

        inc si
        loop s1

        mov ax, 4c00h    
        int 21h

printNumber:

        mov bl, 10
        div bl            ;将两位数分开来输出,先除10,获得十位数,al放商,ah放余数,默认除数为ax
        mov bx, ax
        mov dl, bl
        or dl, 30h      ;将数字转变成字符
        mov ah, 2     ;显示字符(商)
        int 21h

        mov dl, bh
        or dl, 30h
        mov ah, 2       ; ;显示字符(余数)
        int 21h
        ret             ;回到call

printSpace:
        mov dl, ' '
        mov ah, 2
        int 21h
        ret

code ends
end main

 4. 实验任务4

编写子程序printStr 功能:在指定行、以指定颜色,在屏幕上显示字符串 入口参数 字符串首字符地址 --> ds:si(其中,字符串所在段的段地址—> ds, 字符串起始地址的偏 移地址—> si) 字符串长度 --> cx 字符串颜色 --> bl 指定行 --> bh (取值:0 ~24) 出口参数:无 ; 功能:输出单个字符 mov ah, 2 mov dl, ×× ; ××是待输出的字符,或其ASCⅡ码值 int 21h 1 2 3 4 5 data segment str db 'try' len equ $ - str data ends 1 2 3 4 在主体代码中,两次调用printStr,使得在屏幕最上方以黑底绿字显示字符串,在屏幕最下方以黑 底红色显示字符串

assume ds:data, cs:code

data segment
str db 'try'
len equ $ - str
data ends

code segment
start:
    mov ax,data
    mov ds,ax

    mov si,0
    mov cx,len     ;字符串长度为len赋值给cx
    mov bh,0       ;绿色字符显示在第0行
    mov bl,02h     ;绿色
    call printStr

    mov si,0
    mov cx,len     ;字符串长度为len赋值给cx
    mov bh,24      ;红色字符显示在第24行
    mov bl,04h     ;红色
    call printStr

    mov ax,4c00h
    int 21h

    printStr:
    mov ax,0b800h  ;80*25字符缓冲区
    mov es,ax

    mov al,bh
    mov bh,0a0h   ;一行是160个字节,即a0h总共偏移24行,即偏移地址为24*160个字节
    mul bh             ;mul默认al和mul后面的寄存器相乘,结果放在ax中
    mov bp,ax
    s:
    mov ah,ds:[si];每次取出一个字节给ah
    mov es:[bp],ah;把字母存给显存地址低八位中
    inc bp
    mov es:[bp],bl;将颜色信息存入高八位
    inc bp
    inc si
    loop s
    ret

code ends
end start

 

 

 5. 实验任务5

在80×25彩色字符模式下,在屏幕最后一行正中间显示学号。要求输出窗口蓝底,学号和两侧折线,以 白色前景色显示。 注*: 1. 80×25彩色字符模式显示缓冲区结构,参见教材「实验9 根据材料编程」里的说明。 2. 编写程序实现时,将data段的学号换成自己的学号。

assume ds:data, cs:code

data segment
    stu_no db '201983290384'
    len  = $ - stu_no
data ends

code segment
start:
    mov ax,data
    mov ds,ax

    mov si,0
    mov cx,07D0h;
    mov bh,0
    mov bl,00010111B ;对应蓝底白字
    call printblankspace
    mov si,0
    mov cx,004Fh;
    mov bh,24             ;字符显示在第24行
    mov bl,00010111B;对应蓝底白字
    call printline
    mov si,0
    mov cx,len             ;字符串长度为len赋值给cx
    mov bh,24             ;绿色字符显示在第24行
    mov bl,00010111B;对应蓝底白字
    call printstr


    mov ax,4c00h
    int 21h


    printstr:
    mov ax,0b800h  ;80*25字符缓冲区
    mov es,ax

    mov al,bh
    mov bh,0a0h   ;一行是160个字节,即a0.总共偏移24行,即24*160个字节
    mul bh             ;mul默认al和mul后面的寄存器相乘,结果放在ax中
    add ax,3ch
    mov bp,ax        ;160/2-12/2=74
    s:
    mov ah,ds:[si];每次取出一个字节给ah
    mov es:[bp],ah;把字母存给显存地址低八位中
    inc bp
    mov es:[bp],bl;将颜色信息存入高八位
    inc bp
    inc si
    loop s
    ret

    printline:
    mov ax,0b800h  ;80*25字符缓冲区
    mov es,ax

    mov al,bh
    mov bh,0a0h   ;一行是160个字节,即a0.总共偏移24行,即24*160个字节
    mul bh
    mov bp,ax
    s1:
    mov ah,'-';每次取出一个字节给ah
    mov es:[bp],ah;把字母存给显存地址低八位中
    inc bp
    mov es:[bp],bl;将颜色信息存入高八位
    inc bp
    inc si
    loop s1
    ret

    printblankspace:
    mov ax,0b800h  ;80*25字符缓冲区
    mov es,ax

    mov al,bh
    mov bh,0a0h   ;一行是160个字节,即a0.总共偏移24行,即24*160个字节
    mul bh             ;mul默认al和mul后面的寄存器相乘,结果放在ax中
    mov bp,ax        ;bp为显示字符串开始的位置
    s2:
    mov ah,' '         ;每次取出一个字节给ah
    mov es:[bp],ah;把字母存给显存地址低八位中
    inc bp
    mov es:[bp],bl ;将颜色信息存入高八位
    inc bp
    inc si
    loop s2
    ret



code ends
end start

 

 

原文: https://www.cnblogs.com/-xhh/p/15617206.html

暂无评论